Para o que é usado Office Web Components (OWC) ? - Ajuda Inetweb - Base de Conhecimento
Para o que é usado Office Web Components (OWC) ?
Com o componente Office Web Components você pode gerar gráficos em vários formatos dinamicamente (seja ele GIF, JPG entre outros).
GRÁFICO EM COLUNA
<%
Set oChart = CreateObject("OWC10.ChartSpace")
Set c = oChart.Constants
oChart.Border.Color = c.chColorNone
Dim arrCategorias(3), arrValSP(3), arrValRJ(3)
' críe um array que represente os valores da primeira série.
arrValSP(0) = 1000.00
arrValSP(1) = 2000.00
arrValSP(2) = 3000.00
arrValSP(3) = 4000.00
' críe um array que represente os valores da segunda série.
arrValRJ(0) = 4000.00
arrValRJ(1) = 2000.00
arrValRJ(2) = 3000.00
arrValRJ(3) = 1000.00
' gráfico de coluna com as duas séries e quatro categorias.
arrCategorias(0) = "2001"
arrCategorias(1) = "2002"
arrCategorias(2) = "2003"
arrCategorias(3) = "2004"
With oChart
' inclui um objeto no grafico
.Charts.Add
' tipo de grafico em coluna 3d
.Charts(0).Type = oChart.Constants.chChartTypeColumn3d
' incluindo serie no grafico
.Charts(0).SeriesCollection.Add
' definindo o titulo da serie
.Charts(0).SeriesCollection(0).Caption = "São Paulo"
' adicionando as categorias e os valores da serie Sao Paulo
.Charts(0).SeriesCollection(0).SetData c.chDimCategories, c.chDataLiteral, arrCategorias
.Charts(0).SeriesCollection(0).SetData c.chDimValues, c.chDataLiteral, arrValSP
End With
With oChart
' incluindo serie no grafico
.Charts(0).SeriesCollection.Add
' definindo o titulo da serie
.Charts(0).SeriesCollection(1).Caption = "Rio de Janeiro"
' adicionando as categorias e os valores da serie Rio de Janeiro
.Charts(0).SeriesCollection(1).SetData c.chDimCategories, c.chDataLiteral, arrCategorias
.Charts(0).SeriesCollection(1).SetData c.chDimValues, c.chDataLiteral, arrValRJ
End With
Response.Expires = 0
Response.Buffer = true
Response.Clear
Response.ContentType = "image/gif"
' retorna o grafico para o navegador
Response.BinaryWrite oChart.GetPicture("gif",300, 200)
%>
Obs.: No final do script é necessário atribuir o valor “Nothing” para os objetos criados. Para o exemplo acima ficaria assim:
<% Set objPieChart = Nothing %>
GRÁFICO EM PIZZA
<%
Set oChart = CreateObject("OWC10.ChartSpace")
Set c = oChart.Constants
oChart.Border.Color = c.chColorNone
Dim arrCategorias(3), arrVal(3)
' críe um array que represente os valores
arrVal(0) = 1000
arrVal(1) = 2000
arrVal(2) = 3000
arrVal(3) = 4000
' gráfico de coluna com as duas séries e quatro categorias.
arrCategorias(0) = "2001"
arrCategorias(1) = "2002"
arrCategorias(2) = "2003"
arrCategorias(3) = "2004"
With oChart
' inclui um objeto no grafico
.Charts.Add
' tipo de grafico em coluna 3d
.Charts(0).Type = oChart.Constants.chChartTypePie3d
' incluindo serie no grafico
.Charts(0).SeriesCollection.Add
' definindo o titulo da serie
.Charts(0).SeriesCollection(0).Caption = "Faturamento por Ano - Sao Paulo"
' adicionando as categorias e os valores da serie Sao Paulo
.Charts(0).SeriesCollection(0).SetData c.chDimCategories, c.chDataLiteral, arrCategorias
.Charts(0).SeriesCollection(0).SetData c.chDimValues, c.chDataLiteral, arrVal
.Charts(0).HasLegend = True
.Charts(0).HasTitle = True
End With
Response.Expires = 0
Response.Buffer = true
Response.Clear
Response.ContentType = "image/gif"
' retorna o grafico para o navegador
Response.BinaryWrite oChart.GetPicture("gif",300,200)
%>
Obs.: No final do script é necessário atribuir o valor “Nothing” para os objetos criados. Para o exemplo acima ficaria assim:
<% Set objPieChart = Nothing %>
Há ainda muita informação na Internet sobre Office Web Components. Na Microsoft, visite:
* http://msdn.microsoft.com/library