O que é CDOSYS ? - Ajuda Inetweb - Base de Conhecimento
O que é CDOSYS ?
O CDOSYS é um componente da Microsoft utilizado para viabilizar o envio de emails. Foi introduzido no Windows 2000 para substituir o antigo CDONTS o qual era
a versão desse componente para Windows NT 4.0 (versão anterior ao 2000).
O código abaixo mostra um script onde é realizado o envio do email à conta destinada para esse fim em seu domínio (normalmente contato@seudomínio.com.br). Para testar a funcionalidade basta copiar o conteúdo do mesmo, alterando apenas os dados referentes ao seu domínio junto à inteweb, em seguida salvando o arquivo com o título “envia.asp”.
Antes de iniciarmos, lembramos que é necessária a utilização de uma conta válida de seu domínio, pois apenas é permitido o envio de emails com autenticação via programação:
<%
if request("btnEnviar") = "ok" then
' Conta de seu domínio utilizada para enviar as mensagens.
sEnviaRecebe = "contato@seudominio.com.br"
' Senha da conta utilizada para envio, necessária pela obrigatoriedade de autenticação.
sSenha = "123XXXX"
' Campo do formulário onde o cliente previamente inseriu o email de contato, utilizado para responder ao email recebido.
sResponder = request.form("remetente")
' Campo do formulário onde o cliente insere o título para a mensagem:
sAssunto = request.form("assunto")
' Campo do formulário onde o cliente insere o texto da mensagem:
sMensagem = request.form("mensagem")
' Cria o objeto CDOSYS
Set objCDOSYSMail = Server.CreateObject("CDO.Message")
' Cria o objeto para configuração do SMTP
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.seudominio.com.br"
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport")= 587
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername")= sEnviaRecebe
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword")= sSenha
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
objCDOSYSCon.Fields.update
' Atualiza a configuração do CDOSYS para envio do e-mail
Set objCDOSYSMail.Configuration = objCDOSYSCon
' Configura o remetente(FROM)
objCDOSYSMail.From = sResponder
' Configura o destinatário(TO)
objCDOSYSMail.To = sEnviaRecebe
' Configura o Reply-To(Responder Para)
objCDOSYSMail.ReplyTo = sResponder
' Configura o assunto(SUBJECT)
objCDOSYSMail.Subject = sAssunto
' Para enviar mensagens no formato HTML, altere o TextBody para HtmlBody
objCDOSYSMail.HtmlBody = sMensagem
' Enviando o email:
objCDOSYSMail.Send
' Caso algum erro ocorra, exibe uma notificação ao usuário:
If return <> 0 then
response.write "Erro: " & return
Else
' Pode-se exibir uma mensagem para o usuário, indicando o sucesso do envio:
response.write "Mensagem enviada com sucesso para: <strong>" & sEnviaRecebe & "</strong>"
End If
' Para assegurar uma boa prática de programação, ao final da execução é necessário destruir os objetos previamente criados:
Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing
End If
%>
<html>
<head>
<title>Teste CDOSYS</title>
</head>
<body>
<form action="envia.asp" method="post">
<h2>FOMULÁRIO DE CONTATO: </h2>
<table>
<tr><td>Email:</td><td><input name="remetente" type="text"></td></tr>
<tr><td>Assunto:</td><td><input name="assunto" type="text"></td></tr>
<tr><td>Mensagem:</td><td><input name="mensagem" type="text"></td></tr>
</table>
<input type="submit" name="btnEnviar" value="ok">
</form>
</body>
</html>
IMPORTANTE: A INETWEB não é desenvolvedora deste componente, ficando à nossa responsabilidade somente o suporte na utilização do mesmo. Para maiores informações sobre funcionalidades, recursos, sugestões e reclamações, recomendamos que procure o desenvolvedor responsável do componente.